Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00088_DirectionEightSpriteMaze.ls

Text File | 2004-07-11 | 6.0 KB | 205 lines

--
-- DirectionSprite
--

property ancestor

-- constants:
property dragTopSpriteColor  -- the spriteColor of the dragging sprite - for setup
property dragUnderSpriteColor

property dragTopSprite  -- the spriteNumber of the dragging sprite
property dragUnderSprite  -- the sprite that drags under the cursor to find intersecting sprites.
property hiliteSprite  -- the sprite that will do the rollover hiliting

property hiliteList  -- a list of hilitable sprites.  They hilite when the dragger is over them.
property void  -- never initialize this.
property baseCastlib
property showDirectionFlag  -- allow visual changes of direction if true


on new me
  -- set constants:
  set dragTopSpriteColor = 5  -- red
  set dragUnderSpriteColor = 4  -- pink

  -- initialize the ancestor:
  set ancestor = new (script "SinglePointPusher")

  -- do other initializations:
  setUp (me)
  set showDirectionFlag = TRUE

  set hiliteList = []
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end



-- don't allow a visual change of direction:

on showDirectionOff me
  set showDirectionFlag = FALSe
end


on move me, spr, direction

  if voidP (baseCastLib) then set baseCastLib = the name of castLib the castLibNum of sprite spr

  puppetSprite spr, TRUE

  if showDirectionFlag then
    case (direction) of
      #up : set the castLibNum of sprite spr to the number of castLib baseCastLib
      #down:  set the castLibNum of sprite spr to the number of castLib (baseCastLib & "2")
      #right: set the castLibNum of sprite spr to the number of castLib (baseCastLib & "3")
      #left:  set the castLibNum of sprite spr to the number of castLib (baseCastLib & "4")
      #upleft: set the castLibNum of sprite spr to the number of castLib (baseCastLib & "5")
      #upright: set the castLibNum of sprite spr to the number of castLib (baseCastLib & "6")
      #downleft: set the castLibNum of sprite spr to the number of castLib (baseCastLib & "7")
      #downright: set the castLibNum of sprite spr to the number of castLib (baseCastLib & "8")
      otherwise return
    end case
  end if

  if dragTopSprite then
    set the memberNum of sprite dragTopSprite to the memberNum of sprite spr
    set the castLibNum of sprite dragTopSprite to the castLibNum of sprite spr
    set the loc of sprite dragTopSprite to the loc of sprite spr
    updateStage
  end if

  moveOffScreen (me, spr)

  if dragUnderSprite then
    puppetSprite dragUnderSprite, TRUE
    set the member of sprite dragUnderSprite to member "underCursor"
    set the loc of sprite dragUnderSprite to the loc of sprite dragTopSprite
  end if

  moveDirection (me, spr, direction) -- do the actual motion.

  if dragTopSprite then set tmpLoc = the loc of sprite dragTopSprite

  -- this was to return the location of the drag under sprite, currently we return the sprite number itself.
  --  if dragUnderSprite then set endLoc = the loc of sprite dragUnderSprite
  --  else set endLoc = void

  if dragTopSprite then moveOffScreen (me, dragTopSprite)

  set the loc of sprite spr to tmpLoc  -- move original spr back onscreen.
  updateStage

  if dragUnderSprite then return dragUnderSprite
  else return void
end


-- drag the passed sprite

on moveDirection me, spr, direction

  set startCast = the name of castLib the castLibNum of sprite spr
  set betweenCastOne = startCast && "betweens1"
  set betweenCastTwo = startCast && "betweens2"
  set moveNum = 1

  repeat while the mouseDown
    case (direction) of
      #up :   set sprOffSet = point (0,-2)
      #down:  set sprOffSet = point (0,2)
      #right: set sprOffSet = point (2,0)
      #left:  set sprOffSet = point (-2,0)
      #upleft: set sprOffSet = point (-2,-2)
      #downleft: set sprOffSet = point (-2,2)
      #downright: set sprOffSet = point (2,2)
      #upright: set sprOffSet = point (2,-2)
      otherwise return
    end case

    set the loc of sprite dragUnderSprite = the loc of sprite dragUnderSprite + sprOffSet
    updateStage

    if  checkSpriteIntersect (me, dragUnderSprite) then
      -- if we colide with a bad target, then don't allow the move
      set the loc of sprite dragUnderSprite = the loc of sprite dragUnderSprite - sprOffSet
      -- beep
      exit repeat
    else
      -- otherwise move the main sprite to match the new location of the test sprite:
      set the loc of sprite dragTopSprite = the loc of sprite dragTopSprite + sprOffSet
      if the name of castLib the castLibNum of sprite dragTopSprite = startCast then
        set the castLibNum of sprite dragTopSprite to the number of castLib betweenCastOne
      else
        if the name of castLib the castLibNum of sprite dragTopSprite = betweenCastOne then
          set the castLibNum of sprite dragTopSprite to the number of castLib betweenCastTwo
        else
          set the castLibNum of sprite dragTopSprite to the number of castLib startCast
        end if

      end if
    end if

    updateStage
  end repeat
end


--finally ditch the dragUnderSprite:

on hideUnderSprite me
  if not dragUnderSprite then return
  moveOffScreen (me, dragUnderSprite)
end


-- check the ink of the sprites under the cursor:

on checkSpriteIntersect me, activeSpr
  if not dragUnderSprite then return
  if not listP (hiliteList) then return
  updateStage
  if (sprite activeSpr within sprite 3) then
    return 0
  else
    return 1
  end if

end



on setUp me, hilites
  set dragUnderSprite = 0
  set dragTopSprite = 0

  repeat with i = 1 to numSprites (me)
    if the scoreColor of sprite i = dragTopSpriteColor then
      set dragTopSprite = i
      exit repeat
    end if
  end repeat

  repeat with i = 1 to numSprites (me)
    if the scoreColor of sprite i = dragUnderSpriteColor then
      if hiliteSprite then set dragUnderSprite = i
      else set hiliteSprite = i
    end if
  end repeat

  -- makeField (me, dragTopField, dragTopSprite)
end


-- hilites must be a list of sprite numbers.

on initHilitePool me, hilites
  if listP (hilites) then set hiliteList = hilites
end